TotalView MPI Exercise 3

Assignment

Your assignment is to use TotalView to locate an error in the following program. 3-P MPI scatter example. In this example, one process is generated a 3-elements array and scatters one element to each of the processes. But when running the job, I got the results very strange:

szhang@altix [~/MPE] % mpirun -np 3 ./scatter
  Scatter data rank =            0 : irecv=            1
  Scatter data rank =            1 : irecv=        56272
  Scatter data rank =            2 : irecv=        56272

The correct answer should be: 
szhang@altix [~/MPE] % mpirun -np 3 ./scatter
  Scatter data rank =            0 : irecv=            1
  Scatter data rank =            1 : irecv=            2
  Scatter data rank =            2 : irecv=            3

       program scatter
       implicit none
       include 'mpif.h'
       integer isend(3), recv, rank, size, irecv
       integer iwork(4), iprint,itag,istatus(MPI_STATUS_SIZE)
       integer sbuf, rbuf,ierr, i, nmax
       data iwork /6,11,2,4/

       call MPI_INIT(ierr)
       call MPI_COMM_RANK(MPI_COMM_WORLD, rank, ierr)
       call MPI_COMM_SIZE(MPI_COMM_WORLD, size, ierr)

       if(iwork(3).eq.0) then
          iprint=6
       else
          iprint=iwork(2)
       end if

       if(iwork(1).eq.0) then
          nmax=100000
       else
          nmax=iwork(1)
          if(nmax.le.0) then
             if (iprint.gt.0) write(*,*)
      &          ' WRONG INPUT IWORK(1)=',iwork(1)
          end if
       end if
       itag = 100
       if (rank == 0) then
         sbuf = nmax
         CALL MPI_SEND(sbuf, 1, MPI_INTEGER, 1, itag,
      +                 MPI_COMM_WORLD, ierr)
       elseif (rank == 1) then
         CALL MPI_RECV(rbuf, 1, MPI_INTEGER, 0, itag,
      +                 MPI_COMM_WORLD, istatus, ierr)
!        print*, ' I RECEIVED irbuf =', rbuf
       end if
       if(rank.eq.0) then
         do i=1,size
            isend(i) = i
         enddo
       call MPI_Scatter(isend, 1, MPI_INTEGER,
      &                irecv, 1, MPI_INTEGER, 0,
      &                MPI_COMM_WORLD, ierr)
       endif
       print *,' Scatter data rank = ', rank,': ','irecv= ',irecv

       call MPI_FINALIZE(ierr)
       end

Details

cut and paste the code into the file scatter.f

ifort -g -lmpi -o scatter scatter.f

mpirun -np 3 ./scatter

Tips

Use TotalView

Set breakpoints to determine what each MPI task is doing.

A solution

The MPI_Scatter call must occur outside of the last if statement. Otherwise, only the root MPI task will see the scatter command.

      program scatter
      implicit none
      include 'mpif.h'
      integer isend(3), recv, rank, size, irecv
      integer iwork(4), iprint,itag,istatus(MPI_STATUS_SIZE)
      integer sbuf, rbuf,ierr, i, nmax
      data iwork /6,11,2,4/

      call MPI_INIT(ierr)
      call MPI_COMM_RANK(MPI_COMM_WORLD, rank, ierr)
      call MPI_COMM_SIZE(MPI_COMM_WORLD, size, ierr)

      if(iwork(3).eq.0) then
         iprint=6
      else
         iprint=iwork(2)
      end if

      if(iwork(1).eq.0) then
         nmax=100000
      else
         nmax=iwork(1)
         if(nmax.le.0) then
            if (iprint.gt.0) write(*,*)
     &          ' WRONG INPUT IWORK(1)=',iwork(1)
         end if
      end if
      itag = 100
      if (rank == 0) then
        sbuf = nmax
        CALL MPI_SEND(sbuf, 1, MPI_INTEGER, 1, itag,
     +                 MPI_COMM_WORLD, ierr)
      elseif (rank == 1) then
        CALL MPI_RECV(rbuf, 1, MPI_INTEGER, 0, itag,
     +                 MPI_COMM_WORLD, istatus, ierr)
!       print*, ' I RECEIVED irbuf =', rbuf
      end if
      if(rank.eq.0) then
        do i=1,size
           isend(i) = i
        enddo
      endif
      call MPI_Scatter(isend, 1, MPI_INTEGER,
     &                irecv, 1, MPI_INTEGER, 0,
     &                MPI_COMM_WORLD, ierr)
      print *,' Scatter data rank = ', rank,': ','irecv= ',irecv

      call MPI_FINALIZE(ierr)
      end